home *** CD-ROM | disk | FTP | other *** search
/ L' Effet Pommier 3 / L'Effet Pommier - Volume 03.iso / Graphismes / 3D / POV-Ray 3.0B5a PPC / POV-Ray 3.0B5a / POVSCN.Scenes / POVSCN / LEVEL2 / EIGHT.POV < prev    next >
Text File  |  1995-12-06  |  3KB  |  126 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // File by Ville Saari
  3. // Copyright (c) 1991 Ferry Island Pixelboys
  4. // NOTE: Requires "eight_.iff"
  5. //
  6. // POV-Ray scene description for two billiard balls
  7. //
  8. // Created: 07-Jan-91
  9. // Updated: 09-Jan-91
  10. //          19-Jan-92 dmf (see below)
  11. //
  12. // If you do some nice modifications or additions to this file, please send
  13. // me a copy. My Internet address is: vsaari@niksula.hut.fi
  14. //
  15. // Modified somewhat by dmf for POV-Ray 2.0:
  16. //  - decreased most ambient values a bit
  17. //  - increased phong_size on balls
  18. //  - fixed the image_map ... interpolation didn't work.
  19. //  - modified the wood on the questick a bit
  20.  
  21.  
  22. #version 3.0
  23. global_settings { assumed_gamma 1.8 }
  24.  
  25. camera {
  26.    location <-15.0, 8.0, -10.0>
  27.    direction <0.0, 0.0, 1.0>
  28.    up <0.0, 1.0, 0.0>
  29.    right <4/3, 0.0, 0.0>
  30.    sky <0.0, 1.0, 0.0>
  31.    look_at <0.0, 5.0, 5.0>
  32. }
  33. background { rgb 0.025 }
  34.  
  35. // tabletop
  36. plane { y, 0.0
  37.    pigment { colour green 0.5 }
  38.    finish {
  39.       ambient 0.2
  40.       diffuse 0.5
  41.       crand 0.08
  42.    }
  43. }
  44.  
  45. // eightball
  46. sphere { <0, 5, 0>, 5.0
  47.    texture {
  48.       pigment { rgb 0.1 }
  49.       finish {
  50.          ambient 0.15
  51.          diffuse 0.2
  52.       }
  53.    }
  54.  
  55.    texture {
  56.       finish {
  57.          ambient 0.15
  58.          diffuse 0.2
  59.          brilliance 1.0
  60.          phong 1.0
  61.          phong_size 90
  62.          reflection 0.15
  63.       }
  64.       pigment {
  65.          image_map { iff "eight_.iff" once
  66.             interpolate 4
  67.          }
  68.          translate <-0.5, -0.5, -0.5>
  69.          scale <4.0, 4.0, 4.0>
  70.          rotate <-30.0, 20.0, -45.0>
  71.          translate 5*y
  72.       }
  73.    }
  74. }
  75. // Cueball
  76. sphere { <0, 5, 10>, 5.0
  77.    pigment { rgb <1, 1, 1> }
  78.    finish {
  79.       ambient 0.2
  80.       diffuse 0.8
  81.       brilliance 1.0
  82.       phong 1.0
  83.       phong_size 80
  84.       reflection 0.15
  85.    }
  86. }
  87.  
  88. // stick
  89. union {
  90.    cone { <0,0,60>, 1.75, <0,0,0>, 1.2
  91.       pigment {
  92.          wood
  93.          turbulence 0.02
  94.          translate <50.0, -50.0, 0.0>
  95.          scale <0.1, 0.1, 1000>
  96.          rotate <-10.0, 0.0, 15.0>
  97.       }
  98.       finish {
  99.          ambient 0.15
  100.          diffuse 0.4
  101.          phong 1.0
  102.          phong_size 20
  103.          reflection 0.15
  104.       }
  105.    }
  106.  
  107.    // Blue tip on stick
  108.    union {
  109.       sphere { <0.0, 0.0, -0.2>, 1.2 scale <1, 1, 0.5> }
  110.       cylinder { <0,0,0> <0,0,0.4>, 1.2 }
  111.       pigment { colour red 0.2 green 0.5 blue 1.0 }
  112.       finish {
  113.          ambient 0.2
  114.          diffuse 0.8
  115.       }
  116.     }
  117.       rotate <-10.0, 0.0, 45.0>
  118.       translate <-4.5, 6.0, 14.5>
  119. }
  120.  
  121. light_source { <-30.0, 30.0, -15.0> rgb 0.8
  122.     area_light <-15, 0, -15> <15, 0, 15>, 5, 5
  123.     jitter
  124.     adaptive 1
  125. }
  126.